mirror of
https://github.com/Gericom/teak-llvm.git
synced 2025-06-29 16:29:00 -04:00
11b02759a3
The paths output from llvm-config --cmakedir and from clang --print-libgcc-file-name can contain backslashes, while CMake can't handle the paths in this form. This matches what compiler-rt already does (since SVN r203789 and r293195). Differential Revision: https://reviews.llvm.org/D48356 llvm-svn: 335172
62 lines
2.3 KiB
CMake
62 lines
2.3 KiB
CMake
function(find_compiler_rt_library name dest)
|
|
if (NOT DEFINED LIBCXX_COMPILE_FLAGS)
|
|
message(FATAL_ERROR "LIBCXX_COMPILE_FLAGS must be defined when using this function")
|
|
endif()
|
|
set(dest "" PARENT_SCOPE)
|
|
set(CLANG_COMMAND ${CMAKE_CXX_COMPILER} ${LIBCXX_COMPILE_FLAGS}
|
|
"--rtlib=compiler-rt" "--print-libgcc-file-name")
|
|
if (CMAKE_CXX_COMPILER_ID MATCHES Clang AND CMAKE_CXX_COMPILER_TARGET)
|
|
list(APPEND CLANG_COMMAND "--target=${CMAKE_CXX_COMPILER_TARGET}")
|
|
endif()
|
|
execute_process(
|
|
COMMAND ${CLANG_COMMAND}
|
|
RESULT_VARIABLE HAD_ERROR
|
|
OUTPUT_VARIABLE LIBRARY_FILE
|
|
)
|
|
string(STRIP "${LIBRARY_FILE}" LIBRARY_FILE)
|
|
file(TO_CMAKE_PATH "${LIBRARY_FILE}" LIBRARY_FILE)
|
|
string(REPLACE "builtins" "${name}" LIBRARY_FILE "${LIBRARY_FILE}")
|
|
if (NOT HAD_ERROR AND EXISTS "${LIBRARY_FILE}")
|
|
message(STATUS "Found compiler-rt library: ${LIBRARY_FILE}")
|
|
set(${dest} "${LIBRARY_FILE}" PARENT_SCOPE)
|
|
else()
|
|
message(STATUS "Failed to find compiler-rt library")
|
|
endif()
|
|
endfunction()
|
|
|
|
function(find_compiler_rt_dir dest)
|
|
if (NOT DEFINED LIBCXX_COMPILE_FLAGS)
|
|
message(FATAL_ERROR "LIBCXX_COMPILE_FLAGS must be defined when using this function")
|
|
endif()
|
|
set(dest "" PARENT_SCOPE)
|
|
if (APPLE)
|
|
set(CLANG_COMMAND ${CMAKE_CXX_COMPILER} ${LIBCXX_COMPILE_FLAGS}
|
|
"-print-file-name=lib")
|
|
execute_process(
|
|
COMMAND ${CLANG_COMMAND}
|
|
RESULT_VARIABLE HAD_ERROR
|
|
OUTPUT_VARIABLE LIBRARY_DIR
|
|
)
|
|
string(STRIP "${LIBRARY_DIR}" LIBRARY_DIR)
|
|
file(TO_CMAKE_PATH "${LIBRARY_DIR}" LIBRARY_DIR)
|
|
set(LIBRARY_DIR "${LIBRARY_DIR}/darwin")
|
|
else()
|
|
set(CLANG_COMMAND ${CMAKE_CXX_COMPILER} ${LIBCXX_COMPILE_FLAGS}
|
|
"--rtlib=compiler-rt" "--print-libgcc-file-name")
|
|
execute_process(
|
|
COMMAND ${CLANG_COMMAND}
|
|
RESULT_VARIABLE HAD_ERROR
|
|
OUTPUT_VARIABLE LIBRARY_FILE
|
|
)
|
|
string(STRIP "${LIBRARY_FILE}" LIBRARY_FILE)
|
|
file(TO_CMAKE_PATH "${LIBRARY_FILE}" LIBRARY_FILE)
|
|
get_filename_component(LIBRARY_DIR "${LIBRARY_FILE}" DIRECTORY)
|
|
endif()
|
|
if (NOT HAD_ERROR AND EXISTS "${LIBRARY_DIR}")
|
|
message(STATUS "Found compiler-rt directory: ${LIBRARY_DIR}")
|
|
set(${dest} "${LIBRARY_DIR}" PARENT_SCOPE)
|
|
else()
|
|
message(STATUS "Failed to find compiler-rt directory")
|
|
endif()
|
|
endfunction()
|